build.gradle

buildscript {
    ext {
        //@formatter:off
        flinkVersion      = '1.18.0'
        springbootVersion = '3.3.5'
        hadoopVersion     = '3.3.4'
        //@formatter:on
    }

    repositories {
        gradlePluginPortal()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:$springbootVersion"
        classpath "io.spring.gradle:dependency-management-plugin:1.1.4"
        classpath "com.palantir.baseline:gradle-baseline-java:4.185.0"
        classpath "com.diffplug.spotless:spotless-plugin-gradle:6.12.1"
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:3.5.0.2730"
        classpath 'org.owasp:dependency-check-gradle:7.4.4'
        classpath "org.openrewrite:plugin:6.28.3"
    }
}

subprojects {
    group 'com.fortycoderplus.flink.ext'
    version "1.0.0"

    apply plugin: 'java'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'idea'
    apply plugin: 'org.openrewrite.rewrite'

    repositories {
        mavenLocal()
        maven {
            url "https://repo.huaweicloud.com/repository/maven/"
        }
        mavenCentral()
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-starter-parent:${springbootVersion}"
        }
    }

    dependencies {
        // lombok
        compileOnly "org.projectlombok:lombok:1.18.24"
        annotationProcessor "org.projectlombok:lombok:1.18.24"
        // mapstruct
        implementation 'org.mapstruct:mapstruct:1.5.3.Final'
        annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.3.Final'

        // jackson
        implementation 'com.fasterxml.jackson.core:jackson-annotations'
        implementation 'com.fasterxml.jackson.core:jackson-core'
        implementation 'com.fasterxml.jackson.core:jackson-databind'
        implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310'
        implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8'

        // flink
        implementation "org.apache.flink:flink-core:$flinkVersion"
        implementation "org.apache.flink:flink-runtime:$flinkVersion"

        // test:junit
        testImplementation "org.junit.jupiter:junit-jupiter-api"
        testImplementation "org.junit.jupiter:junit-jupiter-engine"
        // test:springboot
        testImplementation 'org.springframework.boot:spring-boot-starter-test'

        // rewrite
        rewrite "org.openrewrite.recipe:rewrite-spring:5.25.0"
    }

    rewrite {
        activeRecipe("org.openrewrite.java.spring.boot3.UpgradeSpringBoot_3_3")
    }

    plugins.withType(JavaPlugin) {
        project.sourceCompatibility = JavaVersion.VERSION_17
    }
    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }

    test {
        useJUnitPlatform()
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                groupId = 'com.fortycoderplus.flink.ext'
                artifactId = project.name
                version = project.version

                from components.java

                pom {
                    name = "Flink History Server Extension :: $project.name"
                    description = "Flink History Server Extension :: $project.name"
                    url = 'https://github.com/40coderplus/flink-history-server'
                    developers {
                        developer {
                            id = 'Codingendless'
                            name = 'Codingendless'
                            email = 'codingendless@40coderplus.com'
                        }
                    }
                    scm {
                        connection = 'scm:git:git@github.com:40coderplus/flink-history-server.git'
                        url = 'https://github.com/40coderplus/flink-history-server'
                    }
                }
            }
        }
        repositories {
            maven {
                credentials {
                    username "$nexusUsername"
                    password "$nexusPassword"
                }
                def releasesRepoUrl = "https://maven.40coderplus.com/repository/maven-releases/"
                def snapshotsRepoUrl = "https://maven.40coderplus.com/repository/maven-snapshots/"
                url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
                allowInsecureProtocol = true
            }
        }
    }
}

apply from: 'baseline.gradle'
apply from: 'sonar.gradle'