create-day.civet

fs from fs
path from path
process from process
axios from axios
dotenv from dotenv

dotenv.config()

unless process.env.SESSION
  console.error 'Error: SESSION environment variable not set'
  process.exit 1

unless process.env.YEAR
  console.error 'Error: YEAR environment variable not set'
  process.exit 1

unless process.argv.2
  console.error 'Error: day number not provided'
  process.exit 1

dirName := process.argv.2.padStart 2, '0'
dirPath := path.join process.cwd(), 'src', dirName

unless fs.existsSync dirPath
  fs.mkdirSync dirPath, recursive: true

fs.writeFileSync 
  path.join(dirPath, 'index.civet'),
  `{ log, getLines } from ../utils.civet\n\nlines := getLines import.meta.url\n`
console.log `✅ ${dirName}/index.civet`

fs.writeFileSync
  path.join(dirPath, 'story.md'),
  ''
console.log `✅ ${dirName}/story.md`

day := parseInt dirName
year := parseInt process.env.YEAR 

axios.get `https://adventofcode.com/${year}/day/${day}/input`,
  headers:
    Cookie: `session=${process.env.SESSION}`
  .then { data } =>
    fs.writeFileSync
      path.join(dirPath, 'input.txt'),
      data
    console.log `✅ ${dirName}/input.txt`