RFC: NamedTuple macro for easier type construction

[stevengj]

Following #34498, #34505, and a recent discourse discussion, this PR defines (and exports) a macro @NamedTuple that provides a more convenient struct-like syntax for defining NamedTuple types:

julia> @NamedTuple{a::Int, b::String}
NamedTuple{(:a, :b),Tuple{Int64,String}}

julia> @NamedTuple begin
           a::Int
           b::String
       end
NamedTuple{(:a, :b),Tuple{Int64,String}}

If a ::Type is not specified, it is treated as ::Any (similar to a struct). This will only be useful if #34547 is resolved, however. (Alternatively, the PR could be changed to require a type specifier for all keys.) Abstractly typed fields of NamedTuple work fine.

[StefanKarpinski]

Might be even better to just have real syntax for this...

[stevengj]

Might be even better to just have real syntax for this...

I don't think we would want NamedTuple{a::Int, b::String} (without the @) to work, since these aren't "really" the type parameters. Or did you have something else in mind?

(I suppose that anonymous struct ... end could produce a NamedTuple type, but that is confusing too.)

[StefanKarpinski]

🤷‍♂ maybe the macro syntax is for the best.

[tkf]

Is it too evil to use @NamedTuple in show? Maybe at least for text/plain?

[stevengj]

Is it too evil to use @NamedTuple in show?

I vote for too evil, at least for now. We can reconsider later.

[tkf]

Re #34548 (comment) I'm seeing the effect of esc:

julia> module Demo1
       macro NamedTuple(ex)
           Meta.isexpr(ex, :braces) || Meta.isexpr(ex, :block) ||
               throw(ArgumentError("@NamedTuple expects {...} or begin...end"))
           decls = filter(e -> !(e isa LineNumberNode), ex.args)
           all(e -> e isa Symbol || Meta.isexpr(e, :(::)), decls) ||
               throw(ArgumentError("@NamedTuple must contain a sequence of name or name::type expressions"))
           vars = [QuoteNode(e isa Symbol ? e : e.args[1]) for e in decls]
           types = [esc(e isa Symbol ? :Any : e.args[2]) for e in decls]
           return :(NamedTuple{($(vars...),), Tuple{$(types...)}})
       end
       end  # module Demo1
Main.Demo1

julia> module Demo2
       macro NamedTuple(ex)
           Meta.isexpr(ex, :braces) || Meta.isexpr(ex, :block) ||
               throw(ArgumentError("@NamedTuple expects {...} or begin...end"))
           decls = filter(e -> !(e isa LineNumberNode), ex.args)
           all(e -> e isa Symbol || Meta.isexpr(e, :(::)), decls) ||
               throw(ArgumentError("@NamedTuple must contain a sequence of name or name::type expressions"))
           vars = [QuoteNode(e isa Symbol ? e : e.args[1]) for e in decls]
           types = [e isa Symbol ? :Any : e.args[2] for e in decls]
           return :(NamedTuple{($(vars...),), Tuple{$(types...)}})
       end
       end  # module Demo2
Main.Demo2

julia> struct Foo end

julia> Demo1.@NamedTuple{a::Foo}
NamedTuple{(:a,),Tuple{Foo}}

julia> Demo2.@NamedTuple{a::Foo}
ERROR: UndefVarError: Foo not defined
...

julia> @macroexpand Demo1.@NamedTuple {a::Foo}
:(Main.Demo1.NamedTuple{(:a,), Main.Demo1.Tuple{Foo}})

julia> @macroexpand Demo2.@NamedTuple {a::Foo}
:(Main.Demo2.NamedTuple{(:a,), Main.Demo2.Tuple{Main.Demo2.Foo}})

Maybe this'd be a nice test case?

[stevengj]

win32 test failures seem unrelated (failure in cmdlineargs and downloading curl).

[JeffBezanson]

👍 from triage.