azurerm_sql_failover_group does not recognize the param read_write_endpoint_failover_policy

[chrcaleb]

Community Note

• Please vote on this issue by adding a 👍 reaction to the original issue to help the community and maintainers prioritize this request
• Please do not leave "+1" or "me too" comments, they generate extra noise for issue followers and do not help prioritize the request
• If you are interested in working on this issue or have submitted a pull request, please leave a comment

Affected Resource(s)

azurerm_sql_failover_group

• azurerm_v1.33.1

Terraform Configuration Files

provider "azurerm" {
  version = "~> 1.33.1"
}
resource "azurerm_resource_group" "example" {
    name     = "centralus-dtdb-rg"
    location = "centralus"
}

resource "azurerm_sql_server" "primary" {
    name                         = "blah12345654321-primary"
    resource_group_name          = "${azurerm_resource_group.example.name}"
    location                     = "${azurerm_resource_group.example.location}"
    version                      = "12.0"
    administrator_login          = "sqladmin"
    administrator_login_password = "pa$$$$w0rd"

}

resource "azurerm_sql_server" "secondary" {
    name                         = "blah12345654321-secondary"
    resource_group_name          = "${azurerm_resource_group.example.name}"
    location                     = "centralus"
    version                      = "12.0"
    administrator_login          = "sqladmin"
    administrator_login_password = "pa$$$$w0rd"

}

resource "azurerm_sql_database" "db1" {
  name                = "db1"
  resource_group_name = "${azurerm_sql_server.primary.resource_group_name}"
  location            = "${azurerm_sql_server.primary.location}"
  server_name         = "${azurerm_sql_server.primary.name}"
}

resource "azurerm_sql_failover_group" "example" {
  name                = "blah12345654321-failover-group"
  resource_group_name = "${azurerm_sql_server.primary.resource_group_name}"
  server_name         = "${azurerm_sql_server.primary.name}"
  databases           = ["${azurerm_sql_database.db1.id}"]
  partner_servers {
      id = "${azurerm_sql_server.secondary.id}"
  }

  read_write_endpoint_failover_policy = {
    mode = "Automatic"
    grace_minutes = 60
  }
}

Expected Behavior

I would expect the failover group is created and the database is applied to the the group.

Actual Behavior

The following error is provided and the failover group is not created.
*Error: Unsupported argument

on main.tf line 44, in resource "azurerm_sql_failover_group" "example":
44: read_write_endpoint_failover_policy = {

An argument named "read_write_endpoint_failover_policy" is not expected here.
Did you mean to define a block of type "read_write_endpoint_failover_policy"?*

References

https://www.terraform.io/docs/providers/azurerm/r/sql_failover_group.html

Related Issues

#3901

[katbyte]

Hi @chrcaleb,

It appears the documentation example is wrong. It should be :

resource "azurerm_sql_failover_group" "example" {
  name                = "blah12345654321-failover-group"
  resource_group_name = "${azurerm_sql_server.primary.resource_group_name}"
  server_name         = "${azurerm_sql_server.primary.name}"
  databases           = ["${azurerm_sql_database.db1.id}"]
  partner_servers {
      id = "${azurerm_sql_server.secondary.id}"
  }

  read_write_endpoint_failover_policy {
    mode          = "Automatic"
    grace_minutes = 60
  }
}

[ghost]

This has been released in version 1.34.0 of the provider. Please see the Terraform documentation on provider versioning or reach out if you need any assistance upgrading. As an example:

provider "azurerm" {
    version = "~> 1.34.0"
}
# ... other configuration ...

[ghost]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.

If you feel this issue should be reopened, we encourage creating a new issue linking back to this one for added context. If you feel I made an error 🤖 🙉 , please reach out to my human friends 👉 [email protected]. Thanks!