forked from DavidGriffith/inform6lib
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathgrammar.h
584 lines (451 loc) · 20 KB
/
grammar.h
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
! ==============================================================================
! GRAMMAR: Grammar table entries for the standard verbs library.
!
! Supplied for use with Inform 6 -- Release 6/12-beta1 -- Serial number 140724
!
! Copyright Graham Nelson 1993-2004 and David Griffith 2012-2014
! This code is licensed under either the traditional Inform license as
! described by the DM4 or the Artistic License version 2.0. See the
! file COPYING in the distribution archive or at
! https://github.com/DavidGriffith/inform6lib/
!
! In your game file, Include three library files in this order:
! Include "Parser";
! Include "VerbLib";
! Include "Grammar";
! ==============================================================================
System_file;
#Ifdef LIBRARY_STAGE;
#Iffalse LIBRARY_STAGE >= AFTER_GRAMMAR; ! if not already included
#Iftrue LIBRARY_STAGE == AFTER_VERBLIB; ! if okay to include it
! ------------------------------------------------------------------------------
! The "meta-verbs", commands to the game rather than in the game, come first:
! ------------------------------------------------------------------------------
Verb meta 'brief'
* -> LMode1;
Verb meta 'verbose' 'long'
* -> LMode2;
Verb meta 'superbrief' 'short'
* -> LMode3;
Verb meta 'normal'
* -> LModeNormal;
Verb meta 'notify'
* -> NotifyOn
* 'on' -> NotifyOn
* 'off' -> NotifyOff;
Verb meta 'pronouns' 'nouns'
* -> Pronouns;
Verb meta 'quit' 'q//' 'die'
* -> Quit;
Verb meta 'recording'
* -> CommandsOn
* 'on' -> CommandsOn
* 'off' -> CommandsOff;
Verb meta 'replay'
* -> CommandsRead;
Verb meta 'restart'
* -> Restart;
Verb meta 'restore'
* -> Restore;
Verb meta 'save'
* -> Save;
Verb meta 'score'
* -> Score;
Verb meta 'fullscore' 'full'
* -> FullScore
* 'score' -> FullScore;
Verb meta 'script' 'transcript'
* -> ScriptOn
* 'on' -> ScriptOn
* 'off' -> ScriptOff;
Verb meta 'noscript' 'unscript'
* -> ScriptOff;
Verb meta 'verify'
* -> Verify;
Verb meta 'version'
* -> Version;
#Ifndef NO_PLACES;
Verb meta 'objects'
* -> Objects;
Verb meta 'places'
* -> Places;
#Endif; ! NO_PLACES
! ------------------------------------------------------------------------------
! Debugging grammar
! ------------------------------------------------------------------------------
#Ifdef DEBUG;
Verb meta 'actions'
* -> ActionsOn
* 'on' -> ActionsOn
* 'off' -> ActionsOff;
Verb meta 'changes'
* -> ChangesOn
* 'on' -> ChangesOn
* 'off' -> ChangesOff;
Verb meta 'gonear'
* anynumber -> GoNear
* noun -> Gonear;
Verb meta 'goto'
* anynumber -> Goto;
Verb meta 'random'
* -> Predictable;
Verb meta 'routines' 'messages'
* -> RoutinesOn
* 'on' -> RoutinesOn
* 'verbose' -> RoutinesVerbose
* 'off' -> RoutinesOff;
Verb meta 'scope'
* -> Scope
* anynumber -> Scope
* noun -> Scope;
Verb meta 'showdict' 'dict'
* -> ShowDict
* topic -> ShowDict;
Verb meta 'showobj'
* -> Showobj
* anynumber -> Showobj
* multi -> Showobj;
Verb meta 'showverb'
* special -> Showverb;
Verb meta 'timers' 'daemons'
* -> TimersOn
* 'on' -> TimersOn
* 'off' -> TimersOff;
Verb meta 'trace'
* -> TraceOn
* number -> TraceLevel
* 'on' -> TraceOn
* 'off' -> TraceOff;
Verb meta 'abstract'
* anynumber 'to' anynumber -> XAbstract
* noun 'to' noun -> XAbstract;
Verb meta 'purloin'
* anynumber -> XPurloin
* multi -> XPurloin;
Verb meta 'tree'
* -> XTree
* anynumber -> XTree
* noun -> XTree;
#Ifdef TARGET_GLULX;
Verb meta 'glklist'
* -> Glklist;
#Endif; ! TARGET_
#Endif; ! DEBUG
! ------------------------------------------------------------------------------
! And now the game verbs.
! ------------------------------------------------------------------------------
[ ADirection; if (noun in compass) rtrue; rfalse; ];
Verb 'answer' 'say' 'shout' 'speak'
* topic 'to' creature -> Answer;
Verb 'ask'
* creature 'about' topic -> Ask
* creature 'for' noun -> AskFor
* creature 'to' topic -> AskTo
* 'that' creature topic -> AskTo;
Verb 'attack' 'break' 'crack' 'destroy'
'fight' 'hit' 'kill' 'murder' 'punch'
'smash' 'thump' 'torture' 'wreck'
* noun -> Attack;
Verb 'blow'
* held -> Blow;
Verb 'bother' 'curses' 'darn' 'drat'
* -> Mild
* topic -> Mild;
Verb 'burn' 'light'
* noun -> Burn
* noun 'with' held -> Burn;
Verb 'buy' 'purchase'
* noun -> Buy;
Verb 'climb' 'scale'
* noun -> Climb
* 'up'/'over' noun -> Climb;
Verb 'close' 'cover' 'shut'
* noun -> Close
* 'up' noun -> Close
* 'off' noun -> SwitchOff;
Verb 'consult'
* noun 'about' topic -> Consult
* noun 'on' topic -> Consult;
Verb 'cut' 'chop' 'prune' 'slice'
* noun -> Cut;
Verb 'dig'
* noun -> Dig
* noun 'with' held -> Dig
* 'in' noun -> Dig
* 'in' noun 'with' held -> Dig;
Verb 'disrobe' 'doff' 'shed'
* held -> Disrobe;
Verb 'drink' 'sip' 'swallow'
* noun -> Drink;
Verb 'drop' 'discard'
* multiheld -> Drop
* multiexcept 'in'/'into'/'down' noun -> Insert
* multiexcept 'on'/'onto' noun -> PutOn;
Verb 'throw'
* held 'at'/'against'/'on'/'onto' noun -> ThrowAt;
Verb 'eat'
* held -> Eat;
Verb 'empty'
* noun -> Empty
* 'out' noun -> Empty
* noun 'out' -> Empty
* noun 'to'/'into'/'on'/'onto' noun -> EmptyT;
Verb 'enter' 'cross'
* -> GoIn
* noun -> Enter;
Verb 'examine' 'x//' 'check' 'describe' 'watch'
* noun -> Examine;
Verb 'exit' 'out' 'outside'
* -> Exit
* noun -> Exit;
Verb 'fill'
* noun -> Fill
* noun 'from' noun -> Fill;
Verb 'get'
* 'out'/'off'/'up' 'of'/'from' noun -> Exit
* multi -> Take
* 'in'/'into'/'on'/'onto' noun -> Enter
* 'off' noun -> GetOff
* multiinside 'from'/'off' noun -> Remove;
Verb 'give' 'feed' 'offer' 'pay'
* held 'to' creature -> Give
* creature held -> Give reverse
* 'over' held 'to' creature -> Give;
Verb 'go' 'run' 'walk'
* -> VagueGo
* noun=ADirection -> Go
* noun -> Enter
* 'out'/'outside' -> Exit
* 'in'/'inside' -> GoIn
* 'into'/'in'/'inside'/'through' noun -> Enter;
Verb 'in' 'inside'
* -> GoIn;
Verb 'insert'
* multiexcept 'in'/'into' noun -> Insert;
Verb 'inventory' 'inv' 'i//'
* -> Inv
* 'tall' -> InvTall
* 'wide' -> InvWide;
Verb 'jump' 'hop' 'skip'
* -> Jump
* 'in' noun -> JumpIn
* 'into' noun -> JumpIn
* 'on' noun -> JumpOn
* 'upon' noun -> JumpOn
* 'over' noun -> JumpOver;
Verb 'kiss' 'embrace' 'hug'
* creature -> Kiss;
Verb 'leave'
* -> VagueGo
* noun=ADirection -> Go
* noun -> Exit
* 'into'/'in'/'inside'/'through' noun -> Enter;
Verb 'listen' 'hear'
* -> Listen
* noun -> Listen
* 'to' noun -> Listen;
Verb 'lock'
* noun 'with' held -> Lock;
Verb 'look' 'l//'
* -> Look
* 'at' noun -> Examine
* 'inside'/'in'/'into'/'through'/'on' noun -> Search
* 'under' noun -> LookUnder
* 'up' topic 'in' noun -> Consult
* noun=ADirection -> Examine
* 'to' noun=ADirection -> Examine;
Verb 'no'
* -> No;
Verb 'open' 'uncover' 'undo' 'unwrap'
* noun -> Open
* noun 'with' held -> Unlock;
Verb 'peel'
* noun -> Take
* 'off' noun -> Take;
Verb 'pick'
* 'up' multi -> Take
* multi 'up' -> Take;
Verb 'pray'
* -> Pray;
Verb 'pry' 'prise' 'prize' 'lever' 'jemmy' 'force'
* noun 'with' held -> Unlock
* 'apart'/'open' noun 'with' held -> Unlock
* noun 'apart'/'open' 'with' held -> Unlock;
Verb 'pull' 'drag'
* noun -> Pull;
Verb 'push' 'clear' 'move' 'press' 'shift'
* noun -> Push
* noun noun -> PushDir
* noun 'to' noun -> Transfer;
Verb 'put'
* multiexcept 'in'/'inside'/'into' noun -> Insert
* multiexcept 'on'/'onto' noun -> PutOn
* 'on' held -> Wear
* 'down' multiheld -> Drop
* multiheld 'down' -> Drop;
Verb 'read'
* noun -> Examine
* 'about' topic 'in' noun -> Consult
* topic 'in' noun -> Consult;
Verb 'remove'
* held -> Disrobe
* multi -> Take
* multiinside 'from' noun -> Remove;
Verb 'rub' 'clean' 'dust' 'polish' 'scrub'
'shine' 'sweep' 'wipe'
* noun -> Rub;
Verb 'search'
* noun -> Search;
Verb 'set' 'adjust'
* noun -> Set
* noun 'to' special -> SetTo;
Verb 'show' 'display' 'present'
* creature held -> Show reverse
* held 'to' creature -> Show;
Verb 'shit' 'damn' 'fuck' 'sod'
* -> Strong
* topic -> Strong;
Verb 'sing'
* -> Sing;
Verb 'sit' 'lie'
* 'on' 'top' 'of' noun -> Enter
* 'on'/'in'/'inside' noun -> Enter;
Verb 'sleep' 'nap'
* -> Sleep;
Verb 'smell' 'sniff'
* -> Smell
* noun -> Smell;
Verb 'sorry'
* -> Sorry;
Verb 'squeeze' 'squash'
* noun -> Squeeze;
Verb 'stand'
* -> Exit
* 'up' -> Exit
* 'on' noun -> Enter;
Verb 'swim' 'dive'
* -> Swim;
Verb 'swing'
* noun -> Swing
* 'on' noun -> Swing;
Verb 'switch'
* noun -> Switchon
* noun 'on' -> Switchon
* noun 'off' -> Switchoff
* 'on' noun -> Switchon
* 'off' noun -> Switchoff;
Verb 'take' 'carry' 'hold'
* multi -> Take
* 'off' held -> Disrobe
* multiinside 'from'/'off' noun -> Remove
* 'inventory' -> Inv;
Verb 'taste'
* noun -> Taste;
Verb 'tell'
* creature 'about' topic -> Tell
* creature 'to' topic -> AskTo;
Verb 'think'
* -> Think;
Verb 'tie' 'attach' 'connect' 'fasten' 'fix'
* noun -> Tie
* noun 'to' noun -> Tie;
Verb 'touch' 'feel' 'fondle' 'grope'
* noun -> Touch;
Verb 'transfer'
* noun 'to' noun -> Transfer;
Verb 'turn' 'rotate' 'screw' 'twist' 'unscrew'
* noun -> Turn
* noun 'on' -> Switchon
* noun 'off' -> Switchoff
* 'on' noun -> Switchon
* 'off' noun -> Switchoff;
Verb 'unlock'
* noun 'with' held -> Unlock;
Verb 'wait' 'z//'
* -> Wait;
Verb 'wake' 'awake' 'awaken'
* -> Wake
* 'up' -> Wake
* creature -> WakeOther
* creature 'up' -> WakeOther
* 'up' creature -> WakeOther;
Verb 'wave'
* -> WaveHands
* noun -> Wave
* noun 'at' noun -> Wave
* 'at' noun -> WaveHands;
Verb 'wear' 'don'
* held -> Wear;
Verb 'yes' 'y//'
* -> Yes;
! ------------------------------------------------------------------------------
! This routine is no longer used here, but provided to help existing games
! which use it as a general parsing routine:
[ ConTopic w;
consult_from = wn;
do w = NextWordStopped();
until (w == -1 || (w == 'to' && action_to_be == ##Answer));
wn--;
consult_words = wn - consult_from;
if (consult_words == 0) return -1;
if (action_to_be == ##Answer or ##Ask or ##Tell) {
w = wn; wn = consult_from; parsed_number = NextWord();
if (parsed_number == 'the' && consult_words > 1) parsed_number = NextWord();
wn = w;
return 1;
}
return 0;
];
! ------------------------------------------------------------------------------
! Final task: provide trivial routines if the user hasn't already:
! ------------------------------------------------------------------------------
Default Story 0;
Default Headline 0;
Default d_obj NULL;
Default u_obj NULL;
Stub AfterLife 0;
Stub AfterPrompt 0;
Stub Amusing 0;
Stub BeforeParsing 0;
Stub ChooseObjects 2;
Stub DarkToDark 0;
Stub DeathMessage 0;
Stub Epilogue 0;
Stub GamePostRoutine 0;
Stub GamePreRoutine 0;
Stub InScope 1;
Stub LookRoutine 0;
Stub NewRoom 0;
Stub ObjectDoesNotFit 2;
Stub ParseNumber 2;
Stub ParserError 1;
Stub PrintTaskName 1;
Stub PrintVerb 1;
Stub TimePasses 0;
Stub UnknownVerb 1;
#Ifdef TARGET_GLULX;
Stub HandleGlkEvent 2;
Stub IdentifyGlkObject 4;
Stub InitGlkWindow 1;
#Endif; ! TARGET_GLULX
#Ifndef PrintRank;
[ PrintRank; "."; ];
#Endif;
#Ifndef ParseNoun;
[ ParseNoun obj; obj = obj; return -1; ];
#Endif;
#Ifdef INFIX;
Include "infix";
#Endif;
! ==============================================================================
Undef LIBRARY_STAGE; Constant LIBRARY_STAGE = AFTER_GRAMMAR;
#Ifnot; ! LIBRARY_STAGE < AFTER_GRAMMAR but ~= AFTER_VERBLIB
Message "Error: 'verblib' needs to be correctly included before including 'grammar'. This will cause a big number of errors!";
#Endif;
#Ifnot; ! LIBRARY_STAGE >= AFTER_GRAMMAR : already included
Message "Warning: 'grammar' included twice; ignoring second inclusion. (Ignore this if this is on purpose.)";
#Endif;
#Ifnot; ! LIBRARY_STAGE is not defined
Message "Error: 'parser', then 'verblib' need to be correctly included before including 'grammar'. This will cause a big number of errors!";
#Endif;
! ==============================================================================