feat: migrate from make to just

CONTRIBUTING.md

@@ -25,12 +25,20 @@ This project uses [`uv`](https://github.com/astral-sh/uv) for managing dependenc
 environments.
 
 You can create a virtual environment manually should you wish, though most of that is taken
-care of automatically if you use the `Makefile` provided:
+care of automatically if you use the `justfile` provided. Simply run
+[`just`](https://github.com/casey/just) (you can `snap install just`) to show the available
+commands:
 
 ```shell
-make fmt           # update your code according to linting rules
-make lint          # code style
-make unit          # unit tests
+∮ just                                                                                           12:17:49
+Available recipes:
+    clean                 # Cleanup transient files
+    fmt                   # Format the code
+    generate-requirements # Generate requirements.txt from pyproject.toml
+    integration *args=''  # Run integration tests
+    lint                  # Lint the code
+    lock                  # Update uv.lock with the latest deps
+    unit *args=''         # Run unit tests
 ```
 
 To create the environment manually:

charmcraft.yaml

@@ -26,9 +26,10 @@ parts:
     build-snaps:
       - rustup
       - astral-uv
+      - just
     override-build: |
       rustup toolchain install stable
-      make generate-requirements
+      just generate-requirements
       craftctl default
     prime:
       - -*.charm

justfile

@@ -0,0 +1,73 @@
+set quiet # Recipes are silent by default
+set export # Just variables are exported to the environment
+set positional-arguments # Send positional arguments to Just recipes
+
+PROJECT := invocation_directory()
+
+SRC := PROJECT + "/src"
+TESTS := PROJECT + "/tests"
+ALL := SRC + " " + TESTS
+
+PYTHONPATH := PROJECT + ":" + \
+  SRC + ":" + \
+  PROJECT + "/lib"
+
+# List the available recipes
+[private]
+default:
+  just --list
+
+# Update uv.lock with the latest deps
+lock:
+  uv lock --upgrade --no-cache
+
+# Generate requirements.txt from pyproject.toml
+generate-requirements:
+  uv export --frozen --no-hashes --format=requirements-txt -o requirements.txt
+
+# Lint the code
+lint:
+  uv tool run ruff check $ALL
+  uv tool run ruff format --check --diff $ALL
+
+# Format the code
+fmt:
+  uv tool run ruff check --fix-only $ALL
+  uv tool run ruff format $ALL
+
+# Run unit tests
+unit *args='':
+  uv run --frozen --isolated --all-extras \
+    coverage run \
+    --source=$SRC \
+    -m pytest \
+    --ignore=$TESTS/integration \
+    --tb native \
+    -v \
+    -s \
+    "$@"
+  uv run --all-extras coverage report
+
+# Run integration tests
+integration *args='':
+  uv run --frozen --isolated --all-extras \
+    pytest \
+    -v \
+    -x \
+    -s \
+    --tb native \
+    --ignore=$TESTS/unit \
+    --log-cli-level=INFO \
+    "$@"
+
+# Cleanup transient files
+clean:
+	rm -rf .coverage
+	rm -rf .pytest_cache
+	rm -rf .ruff_cache
+	rm -rf .venv
+	rm -rf *.charm
+	rm -rf *.rock
+	rm -rf **/__pycache__
+	rm -rf **/*.egg-info
+	rm -rf requirements*.txt

spread.yaml

@@ -94,7 +94,7 @@ prepare: |
   fi
 
   snap install --classic concierge
-  concierge prepare --trace -p microk8s --extra-snaps astral-uv --extra-debs make
+  concierge prepare --trace -p microk8s --extra-snaps astral-uv,just
 
   pushd "$SPREAD_PATH"
 

tests/spread/deploy-python/task.yaml

@@ -11,7 +11,7 @@ execute: |
     args="--charm-path=$PWD/zinc-k8s_amd64.charm $args"
   fi
 
-  make integration ARGS="$args"
+  just integration "$args"
 
 restore: |
   if [[ -z "${CI:-}" ]]; then

tests/spread/ingress-path/task.yaml

@@ -12,7 +12,7 @@ execute: |
     args="--charm-path=$PWD/zinc-k8s_amd64.charm $args"
   fi
 
-  make integration ARGS="$args"
+  just integration "$args"
 
 restore: |
   if [[ -z "${CI:-}" ]]; then

tests/spread/ingress/task.yaml

@@ -11,7 +11,7 @@ execute: |
     args="--charm-path=$PWD/zinc-k8s_amd64.charm $args"
   fi
 
-  make integration ARGS="$args"
+  just integration "$args"
 
 restore: |
   if [[ -z "${CI:-}" ]]; then

tests/spread/observability-relations/task.yaml

@@ -12,7 +12,7 @@ execute: |
     args="--charm-path=$PWD/zinc-k8s_amd64.charm $args"
   fi
 
-  make integration ARGS="$args"
+  just integration "$args"
 
 restore: |
   if [[ -z "${CI:-}" ]]; then