settings.gradle

pluginManagement {
    repositories {
        gradlePluginPortal()
        google()
        mavenCentral()
    }
    plugins {
        id "com.android.library" version "8.7.3"
        id "com.android.application" version "8.7.3"
    }
}

plugins {
    id 'io.freefair.settings.plugin-versions' version '8.11'
    id 'org.gradle.toolchains.foojay-resolver-convention' version '0.9.0'
    id "com.gradle.develocity" version "3.19"
}

rootProject.name = 'dart-sass-java'

boolean isCiServer = System.getenv().containsKey("CI")

develocity {
    buildScan {
        publishing.onlyIf { isCiServer }
        termsOfUseUrl = "https://gradle.com/help/legal-terms-of-use"
        termsOfUseAgree = "yes"
    }
}

buildCache {
    remote(HttpBuildCache) {
        url = 'https://build-cache.grefer-hosting.de/cache/'
        push = isCiServer
        credentials {
            username = "larsgrefer"
            password = providers.gradleProperty('larsgreferBuildCachePassword').getOrElse(null)
        }
    }
}

include "sass-embedded-protocol"
include "sass-embedded-host"
include "sass-embedded-bundled"
include "sass-embedded-bundled-ia32"

include "sass-embedded-spring5"
include "sass-embedded-spring6"

include "sass-embedded-android"

include "test-projects:spring-boot-resources"
include "test-projects:graalvm"
include "test-projects:android-app"