build.gradle

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
    }
}

apply plugin: 'idea'
apply plugin: 'java'
apply plugin: 'org.springframework.boot'
apply plugin: 'io.spring.dependency-management'

group = 'com.github.lindenhoney'

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
}

springBoot {
    buildInfo()
}

test {
    useJUnitPlatform()
    testLogging {
        events "failed"
        exceptionFormat "short"

        debug {
            events "started", "skipped", "failed"
            exceptionFormat "full"
        }

        info {
            events "failed", "skipped"
        }
    }
    failFast = true
}

repositories {
    mavenCentral()
}

dependencies {
/**
 *  Spring dependencies
 */
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

/**
 *  Other dependencies
 */
    implementation "org.springdoc:springdoc-openapi-webflux-ui:${springDocVersion}"

    implementation 'io.micrometer:micrometer-registry-prometheus'

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    implementation "org.apache.commons:commons-lang3:${apacheCommonsLangVersion}"

    implementation "org.jsoup:jsoup:${jsoupVersion}"
    implementation 'io.projectreactor.addons:reactor-extra'


/**
 *  Test dependencies
 */
    testImplementation("org.junit.jupiter:junit-jupiter:${junitJupiterVersion}")

    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    testImplementation 'org.springframework.boot:spring-boot-starter-test', {
        exclude group: 'junit', module: 'junit'
    }

    testImplementation 'io.projectreactor:reactor-test'
}