build.gradle

plugins {
    id 'java-gradle-plugin'
    id 'com.gradle.plugin-publish' version '0.12.0'
    id 'org.jetbrains.kotlin.jvm' version '1.4.10'
    id 'groovy'
}

def getVersionAccordingTheTag() {
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'describe', '--abbrev=0', '--tags'
        standardOutput = stdout
    }
    String verByGit = stdout.toString().trim()
    return verByGit
}

group = 'net.hubalek.gradle.s3privaterepo'
version = getVersionAccordingTheTag()

gradlePlugin {
    plugins {
        placeholdersPlugin {
            id = 'net.hubalek.gradle.s3privaterepo'
            displayName = "S3 Private Repo Gradle Plugin"
            description = "Allows to add Amazon S3 private repo just according system properties or environment variables."
            implementationClass = 'net.hubalek.gradle.s3privaterepo.S3PrivateRepo'
        }
    }
}

pluginBundle {
    website = 'https://github.com/thubalek/private-s3-repo-gradle-plugin'
    vcsUrl = 'https://github.com/thubalek/private-s3-repo-gradle-plugin.git'
    tags = ["s3", "aws", "credentials"]
}

repositories {
    mavenCentral()
}
dependencies {
    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
}
compileKotlin {
    kotlinOptions {
        jvmTarget = "1.8"
    }
}