terraform-aws-cloudfront-s3-cdn

Terraform module to provision an AWS CloudFront CDN with an S3 origin.

Tip

👽 Use Atmos with Terraform

Cloud Posse uses atmos to easily orchestrate multiple environments using Terraform.
Works with Github Actions, Atlantis, or Spacelift.

Watch demo of using Atmos with Terraform

Example of running atmos to manage infrastructure from our Quick Start tutorial.

Usage

For a complete example, see examples/complete.

For automated tests of the complete example using bats and Terratest (which tests and deploys the example on AWS), see test.

The following will create a new s3 bucket eg-prod-app for a cloudfront cdn, and allow principal1 to upload to prefix1 and prefix2, while allowing principal2 to manage the whole bucket.

module "cdn" {
  source = "cloudposse/cloudfront-s3-cdn/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  namespace         = "eg"
  stage             = "prod"
  name              = "app"
  aliases           = ["assets.cloudposse.com"]
  dns_alias_enabled = true
  parent_zone_name  = "cloudposse.com"

  deployment_principal_arns = {
    "arn:aws:iam::123456789012:role/principal1" = ["prefix1/", "prefix2/"]
    "arn:aws:iam::123456789012:role/principal2" = [""]
  }
}

The following will reuse an existing s3 bucket eg-prod-app for a cloudfront cdn.

module "cdn" {
  source = "cloudposse/cloudfront-s3-cdn/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  origin_bucket     = "eg-prod-app"
  aliases           = ["assets.cloudposse.com"]
  dns_alias_enabled = true
  parent_zone_name  = "cloudposse.com"
}

The following will create an Origin Group with the origin created by this module as a primary origin and an additional S3 bucket as a failover origin.

module "s3_bucket" {
  source  = "cloudposse/s3-bucket/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  attributes = ["failover-assets"]
}

module "cdn" {
  source = "cloudposse/cloudfront-s3-cdn/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  aliases           = ["assets.cloudposse.com"]
  dns_alias_enabled = true
  parent_zone_name  = "cloudposse.com"
  s3_origins = [{
    domain_name = module.s3_bucket.bucket_regional_domain_name
    origin_id   = module.s3_bucket.bucket_id
    origin_path = null
    s3_origin_config = {
      origin_access_identity = null # will get translated to the origin_access_identity used by the origin created by this module.
    }
  }]
  origin_groups = [{
    primary_origin_id  = null # will get translated to the origin id of the origin created by this module.
    failover_origin_id = module.s3_bucket.bucket_id
    failover_criteria  = [
      403,
      404,
      500,
      502
    ]
  }]
}

Background on CDNs, "Origins", S3 Buckets, and Web Servers

CDNs and Origin Servers

There are some settings you need to be aware of when using this module. In order to understand the settings, you need to understand some of the basics of CDNs and web servers, so we are providing this highly simplified explanation of how they work in order for you to understand the implications of the settings you are providing.

A "CDN" (Content Distribution Network) is a collection of servers scattered around the internet with the aim of making it faster for people to retrieve content from a website. The details of why that is wanted/needed are beyond the scope of this document, as are most of the details of how a CDN is implemented. For this discussion, we will simply treat a CDN as a set of web servers all serving the same content to different users.

In a normal web server (again, greatly simplified), you place files on the server and the web server software receives requests from browsers and responds with the contents of the files.

For a variety of reasons, the web servers in a CDN do not work the way normal web servers work. Instead of getting their content from files on the local server, the CDN web servers get their content by acting like web browsers (proxies). When they get a request from a browser, they make the same request to what is called an "Origin Server". It is called an origin server because it serves the original content of the website, and thus is the origin of the content.

As a website publisher, you put content on an Origin Server (which users usually should be prevented from accessing) and configure your CDN to use your Origin Server. Then you direct users to a URL hosted by your CDN provider, the users' browsers connect to the CDN, the CDN gets the content from your Origin Server, your Origin Server gets the content from a file on the server, and the data gets sent back hop by hop to the user. (The reason this ends up being a good idea is that the CDN can cache the content for a while, serving multiple users the same content while only contacting the origin server once.)

S3 Buckets: file storage and web server

S3 buckets were originally designed just to store files, and they are still most often used for that. The have a lot of access controls to make it possible to strictly limit who can read what files in the bucket, so that companies can store sensitive information there. You may have heard of a number of "data breaches" being caused by misconfigured permissions on S3 buckets, making them publicly accessible. As a result of that, Amazon has some extra settings on top of everything else to keep S3 buckets from being publicly accessible, which is usually a good thing.

However, at some point someone realized that since these files were in the cloud, and Amazon already had these web servers running to provide access to the files in the cloud, it was only a tiny leap to turn an S3 bucket into a web server. So now S3 buckets can be published as websites with a few configuration settings, including making the contents publicly accessible.

Web servers, files, and the different modes of S3 buckets

In the simplest websites, the URL "path" (the part after the site name) corresponds directly to the path (under a special directory we will call /webroot) and name of a file on the web server. So if the web server gets a request for "http://example.com/foo/bar/baz.html" it will look for a file /webroot/foo/bar/baz.html. If it exists, the server will return its contents, and if it does not exist, the server will return a Not Found error. An S3 bucket, whether configured as a file store or a website, will always do both of these things.

Web servers, however, do some helpful extra things. To name a few:

• If the URL ends with a /, as in http://example.com/foo/bar/, the web server (depending on how it is configured) will either return a list of files in the directory or it will return the contents of a file in the directory with a special name (by default, index.html) if it exists.
• If the URL does not end with a / but the last part, instead of being a file name, is a directory name, the web server will redirect the user to the URL with the / at the end instead of saying the file was Not Found. This redirect will get you to the index.html file we just talked about. Given the way people pass URLs around, this turns out to be quite helpful.
• If the URL does not point to a directory or a file, instead of just sending back a cryptic Not Found error code, it can return the contents of a special file called an "error document".

Your Critical Decision: S3 bucket or website?

All of this background is to help you decide how to set website_enabled and s3_website_password_enabled. The default for website_enabled is false which is the easiest to configure and the most secure, and with this setting, s3_website_password_enabled is ignored.

S3 buckets, in file storage mode (website_enabled = false), do none of these extra things that web servers do. If the URL points to a file, it will return the file, and if it does not exactly match a file, it will return Not Found. One big advantage, though, is that the S3 bucket can remain private (not publicly accessible). A second, related advantage is that you can limit the website to a portion of the S3 bucket (everything under a certain prefix) and keep the contents under the the other prefixes private.

S3 buckets configured as static websites (website_enabled = true), however, have these extra web server features like redirects, index.html, and error documents. The disadvantage is that you have to make the entire bucket public (although you can still restrict access to some portions of the bucket).

Another feature or drawback (depending on your point of view) of S3 buckets configured as static websites is that they are directly accessible via their website endpoint as well as through Cloudfront. This module has a feature, s3_website_password_enabled, that requires a password be passed in the HTTP request header and configures the CDN to do that, which will make it much harder to access the S3 website directly. So set s3_website_password_enabled = true to limit direct access to the S3 website or set it to false if you want to be able to bypass Cloudfront when you want to.

In addition to setting website_enabled=true, you must also:

• Specify at least one aliases, like ["example.com"] or ["example.com", "www.example.com"]
• Specify an ACM certificate

Custom Domain Names and Generating a TLS Certificate with ACM

When you set up Cloudfront, Amazon will generate a domain name for your website. You amost certainly will not want to publish that. Instead, you will want to use a custom domain name. This module refers to them as "aliases".

To use the custom domain names, you need to

• Pass them in as aliases so that Cloudfront will respond to them with your content
• Create CNAMEs for the aliases to point to the Cloudfront domain name. If your alias domains are hosted by Route53 and you have IAM permissions to modify them, this module will set that up for you if you set dns_alias_enabled = true.
• Generate a TLS Certificate via ACM that includes the all the aliases and pass the ARN for the certificate in acm_certificate_arn. Note that for Cloudfront, the certificate has to be provisioned in the us-east-1 region regardless of where any other resources are.

# For cloudfront, the acm has to be created in us-east-1 or it will not work
provider "aws" {
  region = "us-east-1"
  alias  = "aws.us-east-1"
}

# create acm and explicitly set it to us-east-1 provider
module "acm_request_certificate" {
  source = "cloudposse/acm-request-certificate/aws"
  providers = {
    aws = aws.us-east-1
  }

  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"
  domain_name                       = "example.com"
  subject_alternative_names         = ["a.example.com", "b.example.com", "*.c.example.com"]
  process_domain_validation_options = true
  ttl                               = "300"
}

module "cdn" {
  source = "cloudposse/cloudfront-s3-cdn/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version     = "x.x.x"
  namespace         = "eg"
  stage             = "prod"
  name              = "app"
  aliases           = ["assets.cloudposse.com"]
  dns_alias_enabled = true
  parent_zone_name  = "cloudposse.com"

  acm_certificate_arn = module.acm_request_certificate.arn

  depends_on = [module.acm_request_certificate]
}

Or use the AWS cli to request new ACM certifiates (requires email validation)

aws acm request-certificate --domain-name example.com --subject-alternative-names a.example.com b.example.com *.c.example.com

NOTE:

Although AWS Certificate Manager is supported in many AWS regions, to use an SSL certificate with CloudFront, it should be requested only in US East (N. Virginia) region.

https://docs.aws.amazon.com/AmazonCloudFront/latest/DeveloperGuide/cnames-and-https-requirements.html

If you want to require HTTPS between viewers and CloudFront, you must change the AWS region to US East (N. Virginia) in the AWS Certificate Manager console before you request or import a certificate.

https://docs.aws.amazon.com/acm/latest/userguide/acm-regions.html

To use an ACM Certificate with Amazon CloudFront, you must request or import the certificate in the US East (N. Virginia) region. ACM Certificates in this region that are associated with a CloudFront distribution are distributed to all the geographic locations configured for that distribution.

This is a fundamental requirement of CloudFront, and you will need to request the certificate in us-east-1 region.

If there are warnings around the outputs when destroying using this module. Then you can use this method for supressing the superfluous errors. TF_WARN_OUTPUT_ERRORS=1 terraform destroy

Lambda@Edge

This module also features a Lambda@Edge submodule. Its lambda_function_association output is meant to feed directly into the variable of the same name in the parent module.

provider "aws" {
  region = var.region
}

provider "aws" {
  region = "us-east-1"
  alias  = "us-east-1"
}

module "lambda_at_edge" {
  source = "cloudposse/cloudfront-s3-cdn/aws//modules/lambda@edge"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  functions = {
    origin_request = {
      source = [{
        content  = <<-EOT
        'use strict';

        exports.handler = (event, context, callback) => {

          //Get contents of response
          const response = event.Records[0].cf.response;
          const headers = response.headers;

          //Set new headers
          headers['strict-transport-security'] = [{key: 'Strict-Transport-Security', value: 'max-age=63072000; includeSubdomains; preload'}];
          headers['content-security-policy'] = [{key: 'Content-Security-Policy', value: "default-src 'none'; img-src 'self'; script-src 'self'; style-src 'self'; object-src 'none'"}];
          headers['x-content-type-options'] = [{key: 'X-Content-Type-Options', value: 'nosniff'}];
          headers['x-frame-options'] = [{key: 'X-Frame-Options', value: 'DENY'}];
          headers['x-xss-protection'] = [{key: 'X-XSS-Protection', value: '1; mode=block'}];
          headers['referrer-policy'] = [{key: 'Referrer-Policy', value: 'same-origin'}];

          //Return modified response
          callback(null, response);
        };
        EOT
        filename = "index.js"
      }]
      runtime      = "nodejs16.x"
      handler      = "index.handler"
      event_type   = "origin-response"
      include_body = false
    }
  }

  # An AWS Provider configured for us-east-1 must be passed to the module, as Lambda@Edge functions must exist in us-east-1
  providers = {
    aws = aws.us-east-1
  }

  context = module.this.context
}


module "cdn" {
  source = "cloudposse/cloudfront-s3-cdn/aws"
  # Cloud Posse recommends pinning every module to a specific version
  # version = "x.x.x"

  ...
  lambda_function_association = module.lambda_at_edge.lambda_function_association
}

Important

In Cloud Posse's examples, we avoid pinning modules to specific versions to prevent discrepancies between the documentation and the latest released versions. However, for your own projects, we strongly advise pinning each module to the exact version you're using. This practice ensures the stability of your infrastructure. Additionally, we recommend implementing a systematic approach for updating versions to avoid unexpected changes.

Makefile Targets

Available targets:

  help                                Help screen
  help/all                            Display help for all targets
  help/short                          This help short screen
  lint                                Lint terraform code

Requirements

Name	Version
terraform	>= 1.3
aws	>= 4.9
random	>= 2.2
time	>= 0.7

Providers

Name	Version
aws	>= 4.9
random	>= 2.2
time	>= 0.7

Modules

Name	Source	Version
dns	cloudposse/route53-alias/aws	0.13.0
logs	cloudposse/s3-log-storage/aws	1.4.2
origin_label	cloudposse/label/null	0.25.0
this	cloudposse/label/null	0.25.0

Resources

Name	Type
aws_cloudfront_distribution.default	resource
aws_cloudfront_origin_access_identity.default	resource
aws_s3_bucket.origin	resource
aws_s3_bucket_acl.origin	resource
aws_s3_bucket_cors_configuration.origin	resource
aws_s3_bucket_ownership_controls.origin	resource
aws_s3_bucket_policy.default	resource
aws_s3_bucket_public_access_block.origin	resource
aws_s3_bucket_server_side_encryption_configuration.origin	resource
aws_s3_bucket_versioning.origin	resource
random_password.referer	resource
time_sleep.wait_for_aws_s3_bucket_settings	resource
aws_iam_policy_document.combined	data source
aws_iam_policy_document.deployment	data source
aws_iam_policy_document.s3_origin	data source
aws_iam_policy_document.s3_ssl_only	data source
aws_iam_policy_document.s3_website_origin	data source
aws_partition.current	data source
aws_region.current	data source
aws_s3_bucket.cf_logs	data source
aws_s3_bucket.origin	data source

Inputs

Name	Description	Type	Default	Required
access_log_bucket_name	DEPRECATED. Use s3_access_log_bucket_name instead.	string	null	no
acm_certificate_arn	Existing ACM Certificate ARN	string	""	no
additional_bucket_policy	Additional policies for the bucket. If included in the policies, the variables ${bucket_name}, ${origin_path} and ${cloudfront_origin_access_identity_iam_arn} will be substituted. It is also possible to override the default policy statements by providing statements with S3GetObjectForCloudFront and S3ListBucketForCloudFront sid.	string	"{}"	no
additional_tag_map	Additional key-value pairs to add to each map in tags_as_list_of_maps. Not added to tags or id. This is for some rare cases where resources want additional configuration of tags and therefore take a list of maps with tag key, value, and additional configuration.	map(string)	{}	no
aliases	List of FQDN's - Used to set the Alternate Domain Names (CNAMEs) setting on Cloudfront	list(string)	[]	no
allow_ssl_requests_only	Set to true to require requests to use Secure Socket Layer (HTTPS/SSL). This will explicitly deny access to HTTP requests	bool	true	no
allowed_methods	List of allowed methods (e.g. GET, PUT, POST, DELETE, HEAD) for AWS CloudFront	list(string)	[ "DELETE", "GET", "HEAD", "OPTIONS", "PATCH", "POST", "PUT" ]	no
attributes	ID element. Additional attributes (e.g. workers or cluster) to add to id, in the order they appear in the list. New attributes are appended to the end of the list. The elements of the list are joined by the delimiter and treated as a single ID element.	list(string)	[]	no
block_origin_public_access_enabled	When set to 'true' the s3 origin bucket will have public access block enabled	bool	false	no
bucket_versioning	State of bucket versioning option	string	"Disabled"	no
cache_policy_id	The unique identifier of the existing cache policy to attach to the default cache behavior. If not provided, this module will add a default cache policy using other provided inputs.	string	null	no
cached_methods	List of cached methods (e.g. GET, PUT, POST, DELETE, HEAD)	list(string)	[ "GET", "HEAD" ]	no
cloudfront_access_log_bucket_name	When cloudfront_access_log_create_bucket is false, this is the name of the existing S3 Bucket where Cloudfront Access Logs are to be delivered and is required. IGNORED when cloudfront_access_log_create_bucket is true.	string	""	no
cloudfront_access_log_create_bucket	When true and cloudfront_access_logging_enabled is also true, this module will create a new, separate S3 bucket to receive Cloudfront Access Logs.	bool	true	no
cloudfront_access_log_include_cookies	Set true to include cookies in Cloudfront Access Logs	bool	false	no
cloudfront_access_log_prefix	Prefix to use for Cloudfront Access Log object keys. Defaults to no prefix.	string	""	no
cloudfront_access_logging_enabled	Set true to enable delivery of Cloudfront Access Logs to an S3 bucket	bool	true	no
cloudfront_origin_access_identity_iam_arn	Existing cloudfront origin access identity iam arn that is supplied in the s3 bucket policy	string	""	no
cloudfront_origin_access_identity_path	Existing cloudfront origin access identity path used in the cloudfront distribution's s3_origin_config content	string	""	no
comment	Comment for the CloudFront distribution	string	"Managed by Terraform"	no
compress	Compress content for web requests that include Accept-Encoding: gzip in the request header	bool	true	no
context	Single object for setting entire context at once. See description of individual variables for details. Leave string and numeric variables as null to use default value. Individual variable settings (non-null) override settings in context object, except for attributes, tags, and additional_tag_map, which are merged.	any	{ "additional_tag_map": {}, "attributes": [], "delimiter": null, "descriptor_formats": {}, "enabled": true, "environment": null, "id_length_limit": null, "label_key_case": null, "label_order": [], "label_value_case": null, "labels_as_tags": [ "unset" ], "name": null, "namespace": null, "regex_replace_chars": null, "stage": null, "tags": {}, "tenant": null }	no
cors_allowed_headers	List of allowed headers for S3 bucket	list(string)	[ "*" ]	no
cors_allowed_methods	List of allowed methods (e.g. GET, PUT, POST, DELETE, HEAD) for S3 bucket	list(string)	[ "GET" ]	no
cors_allowed_origins	List of allowed origins (e.g. example.com, test.com) for S3 bucket	list(string)	[]	no
cors_expose_headers	List of expose header in the response for S3 bucket	list(string)	[ "ETag" ]	no
cors_max_age_seconds	Time in seconds that browser can cache the response for S3 bucket	number	3600	no
custom_error_response	List of one or more custom error response element maps	list(object({ error_caching_min_ttl = string error_code = string response_code = string response_page_path = string }))	[]	no
custom_origin_headers	A list of origin header parameters that will be sent to origin	list(object({ name = string, value = string }))	[]	no
custom_origins	A list of additional custom website origins for this distribution.	list(object({ domain_name = string origin_id = string origin_path = string custom_headers = list(object({ name = string value = string })) custom_origin_config = object({ http_port = number https_port = number origin_protocol_policy = string origin_ssl_protocols = list(string) origin_keepalive_timeout = number origin_read_timeout = number }) }))	[]	no
default_root_object	Object that CloudFront return when requests the root URL	string	"index.html"	no
default_ttl	Default amount of time (in seconds) that an object is in a CloudFront cache	number	60	no
delimiter	Delimiter to be used between ID elements. Defaults to - (hyphen). Set to "" to use no delimiter at all.	string	null	no
deployment_actions	List of actions to permit deployment_principal_arns to perform on bucket and bucket prefixes (see deployment_principal_arns)	list(string)	[ "s3:PutObject", "s3:PutObjectAcl", "s3:GetObject", "s3:DeleteObject", "s3:ListBucket", "s3:ListBucketMultipartUploads", "s3:GetBucketLocation", "s3:AbortMultipartUpload" ]	no
deployment_principal_arns	(Optional) Map of IAM Principal ARNs to lists of S3 path prefixes to grant deployment_actions permissions. Resource list will include the bucket itself along with all the prefixes. Prefixes should not begin with '/'.	map(list(string))	{}	no
descriptor_formats	Describe additional descriptors to be output in the descriptors output map. Map of maps. Keys are names of descriptors. Values are maps of the form {<br> format = string<br> labels = list(string)<br>} (Type is any so the map values can later be enhanced to provide additional options.) format is a Terraform format string to be passed to the format() function. labels is a list of labels, in order, to pass to format() function. Label values will be normalized before being passed to format() so they will be identical to how they appear in id. Default is {} (descriptors output will be empty).	any	{}	no
distribution_enabled	Set to false to create the distribution but still prevent CloudFront from serving requests.	bool	true	no
dns_alias_enabled	Create a DNS alias for the CDN. Requires parent_zone_id or parent_zone_name	bool	false	no
dns_allow_overwrite	Allow creation of DNS records in Terraform to overwrite an existing record, if any. This does not affect the ability to update the record in Terraform and does not prevent other resources within Terraform or manual Route 53 changes outside Terraform from overwriting this record. false by default. This configuration is not recommended for most environments	bool	false	no
enabled	Set to false to prevent the module from creating any resources	bool	null	no
encryption_enabled	When set to 'true' the resource will have aes256 encryption enabled by default	bool	true	no
environment	ID element. Usually used for region e.g. 'uw2', 'us-west-2', OR role 'prod', 'staging', 'dev', 'UAT'	string	null	no
error_document	An absolute path to the document to return in case of a 4XX error	string	""	no
external_aliases	List of FQDN's - Used to set the Alternate Domain Names (CNAMEs) setting on Cloudfront. No new route53 records will be created for these	list(string)	[]	no
extra_logs_attributes	Additional attributes to add to the end of the generated Cloudfront Access Log S3 Bucket name. Only effective if cloudfront_access_log_create_bucket is true.	list(string)	[ "logs" ]	no
extra_origin_attributes	Additional attributes to put onto the origin label	list(string)	[ "origin" ]	no
forward_cookies	Specifies whether you want CloudFront to forward all or no cookies to the origin. Can be 'all' or 'none'	string	"none"	no
forward_header_values	A list of whitelisted header values to forward to the origin (incompatible with cache_policy_id)	list(string)	[ "Access-Control-Request-Headers", "Access-Control-Request-Method", "Origin" ]	no
forward_query_string	Forward query strings to the origin that is associated with this cache behavior (incompatible with cache_policy_id)	bool	false	no
function_association	A config block that triggers a CloudFront function with specific actions. See the aws_cloudfront_distribution documentation for more information.	list(object({ event_type = string function_arn = string }))	[]	no
geo_restriction_locations	List of country codes for which CloudFront either to distribute content (whitelist) or not distribute your content (blacklist)	list(string)	[]	no
geo_restriction_type	Method that use to restrict distribution of your content by country: none, whitelist, or blacklist	string	"none"	no
http_version	The maximum HTTP version to support on the distribution. Allowed values are http1.1, http2, http2and3 and http3	string	"http2"	no
id_length_limit	Limit id to this many characters (minimum 6). Set to 0 for unlimited length. Set to null for keep the existing setting, which defaults to 0. Does not affect id_full.	number	null	no
index_document	Amazon S3 returns this index document when requests are made to the root domain or any of the subfolders	string	"index.html"	no
ipv6_enabled	Set to true to enable an AAAA DNS record to be set as well as the A record	bool	true	no
label_key_case	Controls the letter case of the tags keys (label names) for tags generated by this module. Does not affect keys of tags passed in via the tags input. Possible values: lower, title, upper. Default value: title.	string	null	no
label_order	The order in which the labels (ID elements) appear in the id. Defaults to ["namespace", "environment", "stage", "name", "attributes"]. You can omit any of the 6 labels ("tenant" is the 6th), but at least one must be present.	list(string)	null	no
label_value_case	Controls the letter case of ID elements (labels) as included in id, set as tag values, and output by this module individually. Does not affect values of tags passed in via the tags input. Possible values: lower, title, upper and none (no transformation). Set this to title and set delimiter to "" to yield Pascal Case IDs. Default value: lower.	string	null	no
labels_as_tags	Set of labels (ID elements) to include as tags in the tags output. Default is to include all labels. Tags with empty values will not be included in the tags output. Set to [] to suppress all generated tags. Notes: The value of the name tag, if included, will be the id, not the name. Unlike other null-label inputs, the initial setting of labels_as_tags cannot be changed in later chained modules. Attempts to change it will be silently ignored.	set(string)	[ "default" ]	no
lambda_function_association	A config block that triggers a lambda@edge function with specific actions	list(object({ event_type = string include_body = bool lambda_arn = string }))	[]	no
log_expiration_days	Number of days after object creation to expire Cloudfront Access Log objects. Only effective if cloudfront_access_log_create_bucket is true.	number	90	no
log_glacier_transition_days	Number of days after object creation to move Cloudfront Access Log objects to the glacier tier. Only effective if cloudfront_access_log_create_bucket is true.	number	60	no
log_include_cookies	DEPRECATED. Use cloudfront_access_log_include_cookies instead.	bool	null	no
log_prefix	DEPRECATED. Use cloudfront_access_log_prefix instead.	string	null	no
log_standard_transition_days	Number of days after object creation to move Cloudfront Access Log objects to the infrequent access tier. Only effective if cloudfront_access_log_create_bucket is true.	number	30	no
log_versioning_enabled	Set true to enable object versioning in the created Cloudfront Access Log S3 Bucket. Only effective if cloudfront_access_log_create_bucket is true.	bool	false	no
logging_enabled	DEPRECATED. Use cloudfront_access_logging_enabled instead.	bool	null	no
max_ttl	Maximum amount of time (in seconds) that an object is in a CloudFront cache	number	31536000	no
min_ttl	Minimum amount of time that you want objects to stay in CloudFront caches	number	0	no
minimum_protocol_version	Cloudfront TLS minimum protocol version. If var.acm_certificate_arn is unset, only "TLSv1" can be specified. See: AWS Cloudfront create-distribution documentation and Supported protocols and ciphers between viewers and CloudFront for more information. Defaults to "TLSv1.2_2019" unless var.acm_certificate_arn is unset, in which case it defaults to TLSv1	string	""	no
name	ID element. Usually the component or solution name, e.g. 'app' or 'jenkins'. This is the only ID element not also included as a tag. The "name" tag is set to the full id string. There is no tag with the value of the name input.	string	null	no
namespace	ID element. Usually an abbreviation of your organization name, e.g. 'eg' or 'cp', to help ensure generated IDs are globally unique	string	null	no
ordered_cache	An ordered list of cache behaviors resource for this distribution. List in order of precedence (first match wins). This is in addition to the default cache policy. Set target_origin_id to "" to specify the S3 bucket origin created by this module.	list(object({ target_origin_id = string path_pattern = string allowed_methods = list(string) cached_methods = list(string) compress = bool trusted_signers = list(string) trusted_key_groups = list(string) cache_policy_id = string origin_request_policy_id = string viewer_protocol_policy = string min_ttl = number default_ttl = number max_ttl = number response_headers_policy_id = string forward_query_string = bool forward_header_values = list(string) forward_cookies = string forward_cookies_whitelisted_names = list(string) lambda_function_association = list(object({ event_type = string include_body = bool lambda_arn = string })) function_association = list(object({ event_type = string function_arn = string })) }))	[]	no
origin_bucket	Name of an existing S3 bucket to use as the origin. If this is not provided, it will create a new s3 bucket using var.name and other context related inputs	string	null	no
origin_force_destroy	Delete all objects from the bucket so that the bucket can be destroyed without error (e.g. true or false)	bool	false	no
origin_groups	List of Origin Groups to create in the distribution. The values of primary_origin_id and failover_origin_id must correspond to origin IDs existing in var.s3_origins or var.custom_origins. If primary_origin_id is set to null or "", then the origin id of the origin created by this module will be used in its place. This is to allow for the use case of making the origin created by this module the primary origin in an origin group.	list(object({ primary_origin_id = string failover_origin_id = string failover_criteria = list(string) }))	[]	no
origin_path	An optional element that causes CloudFront to request your content from a directory in your Amazon S3 bucket or your custom origin. It must begin with a /. Do not add a / at the end of the path.	string	""	no
origin_request_policy_id	The unique identifier of the origin request policy that is attached to the behavior. Should be used in conjunction with cache_policy_id.	string	null	no
origin_shield_enabled	If enabled, origin shield will be enabled for the default origin	bool	false	no
origin_ssl_protocols	The SSL/TLS protocols that you want CloudFront to use when communicating with your origin over HTTPS.	list(string)	[ "TLSv1", "TLSv1.1", "TLSv1.2" ]	no
override_origin_bucket_policy	When using an existing origin bucket (through var.origin_bucket), setting this to 'false' will make it so the existing bucket policy will not be overriden	bool	true	no
parent_zone_id	ID of the hosted zone to contain this record (or specify parent_zone_name). Requires dns_alias_enabled set to true	string	""	no
parent_zone_name	Name of the hosted zone to contain this record (or specify parent_zone_id). Requires dns_alias_enabled set to true	string	""	no
price_class	Price class for this distribution: PriceClass_All, PriceClass_200, PriceClass_100	string	"PriceClass_100"	no
query_string_cache_keys	When forward_query_string is enabled, only the query string keys listed in this argument are cached (incompatible with cache_policy_id)	list(string)	[]	no
realtime_log_config_arn	The ARN of the real-time log configuration that is attached to this cache behavior	string	null	no
redirect_all_requests_to	A hostname to redirect all website requests for this distribution to. If this is set, it overrides other website settings	string	""	no
regex_replace_chars	Terraform regular expression (regex) string. Characters matching the regex will be removed from the ID elements. If not set, "/[^a-zA-Z0-9-]/" is used to remove all characters other than hyphens, letters and digits.	string	null	no
response_headers_policy_id	The identifier for a response headers policy	string	""	no
routing_rules	A json array containing routing rules describing redirect behavior and when redirects are applied	string	""	no
s3_access_log_bucket_name	Name of the existing S3 bucket where S3 Access Logs will be delivered. Default is not to enable S3 Access Logging.	string	""	no
s3_access_log_prefix	Prefix to use for S3 Access Log object keys. Defaults to logs/${module.this.id}	string	""	no
s3_access_logging_enabled	Set true to deliver S3 Access Logs to the s3_access_log_bucket_name bucket. Defaults to false if s3_access_log_bucket_name is empty (the default), true otherwise. Must be set explicitly if the access log bucket is being created at the same time as this module is being invoked.	bool	null	no
s3_object_ownership	Specifies the S3 object ownership control on the origin bucket. Valid values are ObjectWriter, BucketOwnerPreferred, and 'BucketOwnerEnforced'.	string	"ObjectWriter"	no
s3_origins	A list of S3 origins (in addition to the one created by this module) for this distribution. S3 buckets configured as websites are custom_origins, not s3_origins. Specifying s3_origin_config.origin_access_identity as null or "" will have it translated to the origin_access_identity used by the origin created by the module.	list(object({ domain_name = string origin_id = string origin_path = string s3_origin_config = object({ origin_access_identity = string }) }))	[]	no
s3_website_password_enabled	If set to true, and website_enabled is also true, a password will be required in the Referrer field of the HTTP request in order to access the website, and Cloudfront will be configured to pass this password in its requests. This will make it much harder for people to bypass Cloudfront and access the S3 website directly via its website endpoint.	bool	false	no
stage	ID element. Usually used to indicate role, e.g. 'prod', 'staging', 'source', 'build', 'test', 'deploy', 'release'	string	null	no
tags	Additional tags (e.g. {'BusinessUnit': 'XYZ'}). Neither the tag keys nor the tag values will be modified by this module.	map(string)	{}	no
tenant	ID element _(Rarely used, not included by default)_. A customer identifier, indicating who this instance of a resource is for	string	null	no
trusted_key_groups	A list of key group IDs that CloudFront can use to validate signed URLs or signed cookies.	list(string)	[]	no
trusted_signers	The AWS accounts, if any, that you want to allow to create signed URLs for private content. 'self' is acceptable.	list(string)	[]	no
versioning_enabled	When set to 'true' the s3 origin bucket will have versioning enabled	bool	true	no
viewer_protocol_policy	Limit the protocol users can use to access content. One of allow-all, https-only, or redirect-to-https	string	"redirect-to-https"	no
wait_for_deployment	When set to 'true' the resource will wait for the distribution status to change from InProgress to Deployed	bool	true	no
web_acl_id	ID of the AWS WAF web ACL that is associated with the distribution	string	""	no
website_enabled	Set to true to enable the created S3 bucket to serve as a website independently of Cloudfront, and to use that website as the origin. See the README for details and caveats. See also s3_website_password_enabled.	bool	false	no

Outputs

Name	Description
aliases	Aliases of the CloudFront distribution.
cf_arn	ARN of AWS CloudFront distribution
cf_domain_name	Domain name corresponding to the distribution
cf_etag	Current version of the distribution's information
cf_hosted_zone_id	CloudFront Route 53 zone ID
cf_id	ID of AWS CloudFront distribution
cf_identity_iam_arn	CloudFront Origin Access Identity IAM ARN
cf_origin_groups	List of Origin Groups in the CloudFront distribution.
cf_origin_ids	List of Origin IDs in the CloudFront distribution.
cf_primary_origin_id	The ID of the origin created by this module.
cf_s3_canonical_user_id	Canonical user ID for CloudFront Origin Access Identity
cf_status	Current status of the distribution
logs	Log bucket resource
s3_bucket	Name of origin S3 bucket
s3_bucket_arn	ARN of origin S3 bucket
s3_bucket_domain_name	Domain of origin S3 bucket
s3_bucket_policy	Final computed S3 bucket policy

Related Projects

Check out these related projects.

• terraform-aws-cloudfront-cdn - Terraform Module that implements a CloudFront Distribution (CDN) for a custom origin.
• terraform-aws-s3-log-storage - S3 bucket with built in IAM policy to allow CloudTrail logs

Tip

Use Terraform Reference Architectures for AWS

Use Cloud Posse's ready-to-go terraform architecture blueprints for AWS to get up and running quickly.

✅ We build it with you.
✅ You own everything.
✅ Your team wins.

📚 Learn More

Cloud Posse is the leading DevOps Accelerator for funded startups and enterprises.

Your team can operate like a pro today.

Ensure that your team succeeds by using Cloud Posse's proven process and turnkey blueprints. Plus, we stick around until you succeed.

Day-0: Your Foundation for Success

• Reference Architecture. You'll get everything you need from the ground up built using 100% infrastructure as code.
• Deployment Strategy. Adopt a proven deployment strategy with GitHub Actions, enabling automated, repeatable, and reliable software releases.
• Site Reliability Engineering. Gain total visibility into your applications and services with Datadog, ensuring high availability and performance.
• Security Baseline. Establish a secure environment from the start, with built-in governance, accountability, and comprehensive audit logs, safeguarding your operations.
• GitOps. Empower your team to manage infrastructure changes confidently and efficiently through Pull Requests, leveraging the full power of GitHub Actions.

Day-2: Your Operational Mastery

• Training. Equip your team with the knowledge and skills to confidently manage the infrastructure, ensuring long-term success and self-sufficiency.
• Support. Benefit from a seamless communication over Slack with our experts, ensuring you have the support you need, whenever you need it.
• Troubleshooting. Access expert assistance to quickly resolve any operational challenges, minimizing downtime and maintaining business continuity.
• Code Reviews. Enhance your team’s code quality with our expert feedback, fostering continuous improvement and collaboration.
• Bug Fixes. Rely on our team to troubleshoot and resolve any issues, ensuring your systems run smoothly.
• Migration Assistance. Accelerate your migration process with our dedicated support, minimizing disruption and speeding up time-to-value.
• Customer Workshops. Engage with our team in weekly workshops, gaining insights and strategies to continuously improve and innovate.

✨ Contributing

This project is under active development, and we encourage contributions from our community.

Many thanks to our outstanding contributors:

For 🐛 bug reports & feature requests, please use the issue tracker.

In general, PRs are welcome. We follow the typical "fork-and-pull" Git workflow.

1. Review our Code of Conduct and Contributor Guidelines.
2. Fork the repo on GitHub
3. Clone the project to your own machine
4. Commit changes to your own branch
5. Push your work back up to your fork
6. Submit a Pull Request so that we can review your changes

NOTE: Be sure to merge the latest changes from "upstream" before making a pull request!

🌎 Slack Community

Join our Open Source Community on Slack. It's FREE for everyone! Our "SweetOps" community is where you get to talk with others who share a similar vision for how to rollout and manage infrastructure. This is the best place to talk shop, ask questions, solicit feedback, and work together as a community to build totally sweet infrastructure.

📰 Newsletter

Sign up for our newsletter and join 3,000+ DevOps engineers, CTOs, and founders who get insider access to the latest DevOps trends, so you can always stay in the know. Dropped straight into your Inbox every week — and usually a 5-minute read.

📆 Office Hours

Join us every Wednesday via Zoom for your weekly dose of insider DevOps trends, AWS news and Terraform insights, all sourced from our SweetOps community, plus a live Q&A that you can’t find anywhere else. It's FREE for everyone!

License

Preamble to the Apache License, Version 2.0

Complete license is available in the LICENSE file.

Licensed to the Apache Software Foundation (ASF) under one
or more contributor license agreements.  See the NOTICE file
distributed with this work for additional information
regarding copyright ownership.  The ASF licenses this file
to you under the Apache License, Version 2.0 (the
"License"); you may not use this file except in compliance
with the License.  You may obtain a copy of the License at

  https://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing,
software distributed under the License is distributed on an
"AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
KIND, either express or implied.  See the License for the
specific language governing permissions and limitations
under the License.

Trademarks

All other trademarks referenced herein are the property of their respective owners.

---

Copyright © 2017-2024 Cloud Posse, LLC