Trim transitioned Go settings on non-Go dependencies

This makes it possible to return to the original settings for non-Go
dependencies, e.g. those in srcs or data. Using this transition on such
an attribute realizes "configuration trimming" when combined with
--experimental_output_directory_naming_scheme=diff_against_baseline.

go/private/rules/BUILD.bazel

@@ -1,7 +1,21 @@
 load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+load("@bazel_skylib//rules:common_settings.bzl", "string_setting")
+load(
+    ":transition.bzl",
+    "TRANSITION_ATTRS",
+)
 
 exports_files(["library.bzl"])
 
+[
+    string_setting(
+        name = "original_" + flag,
+        build_setting_default = "",
+        visibility = ["//visibility:private"],
+    )
+    for flag in TRANSITION_ATTRS
+]
+
 filegroup(
     name = "all_rules",
     srcs = glob(["**/*.bzl"]),

go/private/rules/binary.bzl

@@ -29,6 +29,7 @@ load(
 )
 load(
     "//go/private/rules:transition.bzl",
+    "go_non_go_reset_transition",
     "go_transition_rule",
 )
 load(
@@ -160,6 +161,7 @@ _go_binary_kwargs = {
     "attrs": {
         "srcs": attr.label_list(
             allow_files = go_exts + asm_exts + cgo_exts,
+            cfg = go_non_go_reset_transition,
             doc = """The list of Go source files that are compiled to create the package.
             Only `.go` and `.s` files are permitted, unless the `cgo`
             attribute is set, in which case,
@@ -170,6 +172,7 @@ _go_binary_kwargs = {
         ),
         "data": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """List of files needed by this rule at run-time. This may include data files
             needed or other programs that may be executed. The [bazel] package may be
             used to locate run files; they may appear in different places depending on the
@@ -197,6 +200,7 @@ _go_binary_kwargs = {
         ),
         "embedsrcs": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """The list of files that may be embedded into the compiled package using
             `//go:embed` directives. All files must be in the same logical directory
             or a subdirectory as source files. All source files containing `//go:embed`
@@ -249,6 +253,7 @@ _go_binary_kwargs = {
             """,
         ),
         "cdeps": attr.label_list(
+            cfg = go_non_go_reset_transition,
             doc = """The list of other libraries that the c code depends on.
             This can be anything that would be allowed in [cc_library deps]
             Only valid if `cgo` = `True`.
@@ -358,6 +363,9 @@ _go_binary_kwargs = {
             """,
         ),
         "_go_context_data": attr.label(default = "//:go_context_data"),
+        "_allowlist_function_transition": attr.label(
+            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
+        ),
     },
     "executable": True,
     "toolchains": ["@io_bazel_rules_go//go:toolchain"],

go/private/rules/library.bzl

@@ -27,6 +27,10 @@ load(
     "GoLibrary",
     "INFERRED_PATH",
 )
+load(
+    "//go/private/rules:transition.bzl",
+    "go_non_go_reset_transition",
+)
 
 def _go_library_impl(ctx):
     """Implements the go_library() rule."""
@@ -55,6 +59,7 @@ go_library = rule(
     attrs = {
         "data": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """
             List of files needed by this rule at run-time.
             This may include data files needed or other programs that may be executed.
@@ -64,6 +69,7 @@ go_library = rule(
         ),
         "srcs": attr.label_list(
             allow_files = go_exts + asm_exts + cgo_exts,
+            cfg = go_non_go_reset_transition,
             doc = """
             The list of Go source files that are compiled to create the package.
             Only `.go` and `.s` files are permitted, unless the `cgo` attribute is set,
@@ -106,6 +112,7 @@ go_library = rule(
         ),
         "embedsrcs": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """
             The list of files that may be embedded into the compiled package using `//go:embed`
             directives. All files must be in the same logical directory or a subdirectory as source files.
@@ -133,6 +140,7 @@ go_library = rule(
             """,
         ),
         "cdeps": attr.label_list(
+            cfg = go_non_go_reset_transition,
             doc = """
             List of other libraries that the c code depends on.
             This can be anything that would be allowed in [cc_library deps] Only valid if `cgo = True`.
@@ -164,6 +172,9 @@ go_library = rule(
             """,
         ),
         "_go_context_data": attr.label(default = "//:go_context_data"),
+        "_allowlist_function_transition": attr.label(
+            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
+        ),
     },
     toolchains = ["@io_bazel_rules_go//go:toolchain"],
     doc = """This builds a Go library from a set of source files that are all part of

go/private/rules/test.bzl

@@ -39,6 +39,7 @@ load(
 )
 load(
     "//go/private/rules:transition.bzl",
+    "go_non_go_reset_transition",
     "go_transition_rule",
 )
 load(
@@ -190,6 +191,7 @@ _go_test_kwargs = {
     "attrs": {
         "data": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """List of files needed by this rule at run-time. This may include data files
             needed or other programs that may be executed. The [bazel] package may be
             used to locate run files; they may appear in different places depending on the
@@ -199,6 +201,7 @@ _go_test_kwargs = {
         ),
         "srcs": attr.label_list(
             allow_files = go_exts + asm_exts + cgo_exts,
+            cfg = go_non_go_reset_transition,
             doc = """The list of Go source files that are compiled to create the package.
             Only `.go` and `.s` files are permitted, unless the `cgo`
             attribute is set, in which case,
@@ -226,6 +229,7 @@ _go_test_kwargs = {
         ),
         "embedsrcs": attr.label_list(
             allow_files = True,
+            cfg = go_non_go_reset_transition,
             doc = """The list of files that may be embedded into the compiled package using
             `//go:embed` directives. All files must be in the same logical directory
             or a subdirectory as source files. All source files containing `//go:embed`
@@ -298,6 +302,7 @@ _go_test_kwargs = {
             """,
         ),
         "cdeps": attr.label_list(
+            cfg = go_non_go_reset_transition,
             doc = """The list of other libraries that the c code depends on.
             This can be anything that would be allowed in [cc_library deps]
             Only valid if `cgo` = `True`.
@@ -403,6 +408,9 @@ _go_test_kwargs = {
             default = "//go/tools/builders:lcov_merger",
             cfg = "target",
         ),
+        "_allowlist_function_transition": attr.label(
+            default = "@bazel_tools//tools/allowlists/function_transition_allowlist",
+        ),
     },
     "executable": True,
     "test": True,

go/private/rules/transition.bzl

@@ -37,6 +37,15 @@ load(
     "platform_from_crosstool",
 )
 
+TRANSITION_ATTRS = [
+    "static",
+    "race",
+    "msan",
+    "pure",
+    "linkmode",
+    "tags",
+]
+
 def filter_transition_label(label):
     """Transforms transition labels for the current workspace.
 
@@ -54,6 +63,15 @@ def filter_transition_label(label):
     else:
         return str(Label(label))
 
+def _current_setting(attr):
+    return filter_transition_label("@io_bazel_rules_go//go/config:" + attr)
+
+def _original_setting(attr):
+    return filter_transition_label("@io_bazel_rules_go//go/private/rules:original_" + attr)
+
+_TRANSITIONED_SETTINGS = [_current_setting(attr) for attr in TRANSITION_ATTRS]
+_TRANSITIONED_ORIGINAL_SETTINGS = [_original_setting(attr) for attr in TRANSITION_ATTRS]
+
 def go_transition_wrapper(kind, transition_kind, name, **kwargs):
     """Wrapper for rules that may use transitions.
 
@@ -116,6 +134,7 @@ def _go_transition_impl(settings, attr):
     # In any case, get_mode should mainly be responsible for reporting
     # invalid modes, since it also takes --features flags into account.
 
+    original_settings = settings
     settings = dict(settings)
 
     _set_ternary(settings, attr, "static")
@@ -173,6 +192,15 @@ def _go_transition_impl(settings, attr):
         linkmode_label = filter_transition_label("@io_bazel_rules_go//go/config:linkmode")
         settings[linkmode_label] = linkmode
 
+    for setting, value in settings.items():
+        if not "//go/config:" in setting:
+            continue
+        attr = setting.split(":")[1]
+        if value != original_settings[setting]:
+            settings[_original_setting(attr)] = json.encode(original_settings[setting])
+        else:
+            settings[_original_setting(attr)] = ""
+
     return settings
 
 def _request_nogo_transition(settings, attr):
@@ -218,10 +246,10 @@ go_transition = transition(
         "@io_bazel_rules_go//go/config:pure",
         "@io_bazel_rules_go//go/config:tags",
         "@io_bazel_rules_go//go/config:linkmode",
-    ]],
+    ]] + _TRANSITIONED_ORIGINAL_SETTINGS,
 )
 
-_common_reset_transition_dict = {
+_common_reset_transition_dict = dict({
     "@io_bazel_rules_go//go/config:static": False,
     "@io_bazel_rules_go//go/config:msan": False,
     "@io_bazel_rules_go//go/config:race": False,
@@ -230,7 +258,7 @@ _common_reset_transition_dict = {
     "@io_bazel_rules_go//go/config:debug": False,
     "@io_bazel_rules_go//go/config:linkmode": LINKMODE_NORMAL,
     "@io_bazel_rules_go//go/config:tags": [],
-}
+}, **{setting: "" for setting in _TRANSITIONED_ORIGINAL_SETTINGS})
 
 _reset_transition_dict = dict(_common_reset_transition_dict, **{
     "@io_bazel_rules_go//go/private:bootstrap_nogo": True,
@@ -372,6 +400,28 @@ so we can apply both transitions.
 """,
 )
 
+def _go_non_go_reset_transition_impl(settings, attr):
+    new_settings = {}
+    for flag in TRANSITION_ATTRS:
+        setting = _current_setting(flag)
+        original_setting = _original_setting(flag)
+        original_value = settings[original_setting]
+        if original_value:
+            # Reset to the original value and clear it.
+            new_settings[setting] = json.decode(original_value)
+            new_settings[original_setting] = ""
+        else:
+            new_settings[setting] = settings[setting]
+            new_settings[original_setting] = settings[original_setting]
+
+    return new_settings
+
+go_non_go_reset_transition = transition(
+    implementation = _go_non_go_reset_transition_impl,
+    inputs = _TRANSITIONED_SETTINGS + _TRANSITIONED_ORIGINAL_SETTINGS,
+    outputs = _TRANSITIONED_SETTINGS + _TRANSITIONED_ORIGINAL_SETTINGS,
+)
+
 def _check_ternary(name, value):
     if value not in ("on", "off", "auto"):
         fail('{}: must be "on", "off", or "auto"'.format(name))