Add support for Textidote

ale_linters/tex/textidote.vim

@@ -0,0 +1,47 @@
+" Author: Jordi Altayo <[email protected]>, Juan Pablo Stumpf
+" <[email protected]>
+" Description: support for textidote grammar and syntax checker
+
+call ale#Set('tex_textidote_executable', 'textidote')
+call ale#Set('tex_textidote_options', '--no-color --output singleline')
+" TODO get language from spell spelllang
+call ale#Set('tex_textidote_check_lang', '')
+
+
+function! ale_linters#tex#textidote#GetExecutable(buffer) abort
+    let l:exe = ale#Var(a:buffer, 'tex_textidote_executable')
+    let l:exe .= ' ' . ale#Var(a:buffer, 'tex_textidote_options')
+
+    let l:check_lang = ale#Var(a:buffer, 'tex_textidote_check_lang')
+
+    if !empty(l:check_lang)
+        let l:exe .= ' --check ' . l:check_lang
+    endif
+
+    return l:exe . ' ' . expand('#' . a:buffer . ':t')
+endfunction
+
+function! ale_linters#tex#textidote#Handle(buffer, lines) abort
+    let l:pattern = '.*' . expand('#' . a:buffer . ':t:r') . '\.tex(L\(\d\+\)C\(\d\+\)-L\d\+C\d\+): \(.*\)".*"'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col' : l:match[2] + 0,
+        \   'text': l:match[3],
+        \   'type': 'E',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('tex', {
+\   'name': 'textidote',
+\   'output_stream': 'stdout',
+\   'executable': {b -> ale#Var(b, 'tex_textidote_executable')},
+\   'command': function('ale_linters#tex#textidote#GetExecutable'),
+\   'callback': 'ale_linters#tex#textidote#Handle',
+\})
+

doc/ale-tex.txt

@@ -72,6 +72,33 @@ g:ale_tex_texlab_options                              *g:ale_tex_texlab_options*
   This variable can be changed to modify flags given to texlab.
 
 
+===============================================================================
+textidote                                                   *ale-tex-textidote*
+
+g:ale_tex_textidote_executable                       *g:tex_textidote_executable*
+                                                     *b:tex_textidote_executable*
+  Type: |String|
+  Default: `'textidote'`
+
+  This variable can be changed to change the path to textidote.
+
+
+g:ale_tex_textidote_options                        *g:ale_tex_textidote_options*
+                                                   *b:ale_tex_textidote_options*
+  Type: |String|
+  Default: `'--no-color --output singleline'`
+
+  This variable can be changed to modify flags given to textidote.
+
+
+g:ale_tex_textidote_check_lang                  *g:ale_tex_textidote_check_lang*
+                                                *b:ale_tex_textidote_check_lang*
+  Type: |String|
+  Default: `''`
+
+  If this variable is not empty, the language checker will be used. For
+  supported languages, please refer to the Language Tool website.
+
 
 ===============================================================================
   vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:

doc/ale.txt

@@ -2626,6 +2626,7 @@ documented in additional help files.
     lacheck...............................|ale-tex-lacheck|
     latexindent...........................|ale-tex-latexindent|
     texlab................................|ale-tex-texlab|
+    textidote.............................|ale-tex-textidote|
   texinfo.................................|ale-texinfo-options|
     write-good............................|ale-texinfo-write-good|
   text....................................|ale-text-options|