Add japicmp to every module

build.gradle

@@ -1,6 +1,18 @@
+buildscript {
+    repositories {
+        mavenCentral()
+    }
+
+    dependencies {
+        // https://github.com/melix/japicmp-gradle-plugin/issues/36
+        classpath 'com.google.guava:guava:30.1.1-jre'
+    }
+}
+
 plugins {
     id 'io.franzbecker.gradle-lombok' version '4.0.0'
     id 'com.github.johnrengelman.shadow' version '7.0.0'
+    id 'me.champeau.gradle.japicmp' version '0.2.9' apply false
 }
 
 apply from: "$rootDir/gradle/ci-support.gradle"
@@ -46,6 +58,12 @@ subprojects {
     // specific modules should be excluded from publication
     if ( ! ["test-support", "jdbc-test"].contains(it.name) && !it.path.startsWith(":docs:") && it != project(":docs") ) {
         apply from: "$rootDir/gradle/publishing.gradle"
+
+        if (it.name != "bom") {
+            apply plugin: "me.champeau.gradle.japicmp"
+            tasks.register('japicmp', me.champeau.gradle.japicmp.JapicmpTask)
+            apply from: "$rootDir/gradle/japicmp.gradle"
+        }
     }
 
     test {

core/build.gradle

@@ -1,18 +1,3 @@
-buildscript {
-    repositories {
-        jcenter()
-    }
-
-    dependencies {
-        // https://github.com/melix/japicmp-gradle-plugin/issues/36
-        classpath 'com.google.guava:guava:30.1.1-jre'
-    }
-}
-
-plugins {
-    id 'me.champeau.gradle.japicmp' version '0.2.9'
-}
-
 apply plugin: 'com.github.johnrengelman.shadow'
 
 description = "Testcontainers Core"
@@ -24,7 +9,6 @@ sourceSets {
 idea.module.testSourceDirs += sourceSets.jarFileTest.allSource.srcDirs
 
 configurations {
-    baseline
     shaded
     [api, compileOnly, testCompile]*.extendsFrom shaded
 }
@@ -56,17 +40,7 @@ task jarFileTest(type: Test) {
 }
 project.tasks.check.dependsOn(jarFileTest)
 
-task japicmp(type: me.champeau.gradle.japicmp.JapicmpTask) {
-    dependsOn(tasks.shadowJar)
-
-    oldClasspath = configurations.baseline
-    newClasspath = shadowJar.outputs.files
-    ignoreMissingClasses = true
-
-    accessModifier = "protected"
-    failOnModification = true
-    failOnSourceIncompatibility = true
-
+tasks.japicmp {
     packageExcludes = [
         "com.github.dockerjava.*",
         "org.testcontainers.shaded.*",
@@ -77,14 +51,6 @@ task japicmp(type: me.champeau.gradle.japicmp.JapicmpTask) {
     methodExcludes = []
 
     fieldExcludes = []
-
-    onlyBinaryIncompatibleModified = true
-    htmlOutputFile = file("$buildDir/reports/japi.html")
-}
-// do not run on Windows by default
-// TODO investigate zip issue on Windows
-if (!org.gradle.internal.os.OperatingSystem.current().isWindows()) {
-    project.tasks.check.dependsOn(japicmp)
 }
 
 configurations.all {

gradle/japicmp.gradle

@@ -0,0 +1,29 @@
+configurations {
+    baseline
+}
+
+dependencies {
+    baseline "org.testcontainers:${project.name}:1.16.0", {
+        exclude group: "*", module: "*"
+    }
+}
+
+tasks.japicmp {
+    dependsOn(tasks.shadowJar)
+
+    oldClasspath = configurations.baseline
+    newClasspath = shadowJar.outputs.files
+    ignoreMissingClasses = true
+
+    accessModifier = "protected"
+    failOnModification = true
+    failOnSourceIncompatibility = true
+
+    onlyBinaryIncompatibleModified = true
+    htmlOutputFile = file("$buildDir/reports/japi.html")
+}
+// do not run on Windows by default
+// TODO investigate zip issue on Windows
+if (!org.gradle.internal.os.OperatingSystem.current().isWindows()) {
+    project.tasks.check.dependsOn(japicmp)
+}

modules/kafka/build.gradle

@@ -1,5 +1,14 @@
 description = "Testcontainers :: Kafka"
 
+tasks.japicmp {
+    // TODO clean after 1.17.0 is released
+    methodExcludes = [
+        // Overrides removed, not a breaking change per se
+        "org.testcontainers.containers.KafkaContainer#containerIsStarting(com.github.dockerjava.api.command.InspectContainerResponse,boolean)",
+        "org.testcontainers.containers.KafkaContainer#doStart()",
+    ]
+}
+
 dependencies {
     api project(':testcontainers')